FANDOM


WepIconDWN055-NoiseCrush Noise Crush Shademansprite
NoiseCrushWepGif
Weapon code NoiseCrushWep
Comes from Mega Man 7
Weapon color scheme Lilac on azure
Fire rate Slow-Medium
Missile speed Slow (Sound wave)

Medium (Powerful sound wave)

Capacity 14 uses
Weapon hotkey/type [2] Long range
Damage 20 /\/ (Sound Wave)

75 (Charged Sound Wave)

Appears in
these maps
MM8Astro2MM4CossackMM6MrXMM7ShadeMM3WilyMM7Wily1MM7Wily2MM4SkullMM8TenguMM1TimeMM6TomahawkMM2WoodIcyfortsMol ten mountainsTurborumbleSpacedustSacredshrines

Noise Crush generates a heavy sound wave that bounces on solid surfaces once before disappearing. It can be charged by being hit by your own reflected shot. Unlike in Mega Man 7 where it was possible to catch the wave by sliding, the shot must be reflected to be absorbed. Once charged, Noise Crush fires a much larger and stronger sound wave that travels faster but cannot reflect off walls. Note that only the uncharged shot will use ammunition.

Tactics

Using Noise Crush

Because it can only bounce once, Noise Crush is inefficient for spamming in enclosed spaces. Relying on its uncharged version is a bad idea in general. Instead, charge a shot and ambush opponents with it. Then, finish them off with uncharged shots or a different weapon. If you need to recharge mid-battle, jump while firing straight down to get the charge without making yourself vulnerable.

Vs. Noise Crush

Be listening for the distinct noise a foe with a charged Noise Crush will make before they can surprise you. Dodge the charged wave and punish them with any high-damaging weapon of your choice. The uncharged shots are very slow and weak, so feel free to go all out. Just don't let them charge another shot and be ready if they immediately switch weapons.


Code

actor NoiseCrushWep : MegaBuster 10083
{
//$Category MM8BDM-Weapons
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 2
Obituary "%o was silenced by %k's Noise Crush."
Inventory.Pickupmessage "Power up! Noise Crush!"
weapon.ammotype "NoiseCrushAmmo"
inventory.pickupsound "weapon/weaponup"
+WEAPON.AMMO_OPTIONAL
inventory.icon "NCRUSI"
Scale 2.0
States
{
Spawn:
WEA3 J 1
loop
Ready:
NCRU I 0 ACS_ExecuteAlways(998,0,55)
NCRU I 0 A_JumpIfInventory("NoiseCrushFlag",1,"Charged")
NCRU I 1 A_WeaponReady
Goto Ready+1
Charged:
NCRU L 0 A_GunFlash
NCRU L 0 ACS_ExecuteAlways(991,0,72)
NCRU M 1 A_WeaponReady
NCRU L 0 ACS_ExecuteAlways(991,0,73)
NCRU N 1 A_WeaponReady
NCRU I 0 ACS_ExecuteAlways(991,0,55)
NCRU I 1 A_WeaponReady
Goto Charged+1
Flash:
TNT1 H 5 A_PlaySoundEx("weapon/noisecrushcharge", "Voice")
TNT1 H 0 A_JumpIfInventory("NoiseCrushFlag",1,"Flash")
stop
Deselect:
TNT1 A 0 A_JumpIfInventory("NoiseCrushFlag",1,"FireOut")
TNT1 A 0 A_TakeInventory("NoiseCrushFlag",1)
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
NCRU I 1 A_Lower
Loop
Select:
TNT1 A 0 A_TakeInventory("NoiseCrushFlag",1)
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
NCRU I 1 A_Raise
Loop
Fire:
NCRU I 0 A_JumpIfInventory("NoiseCrushFlag",1,"Fire2")
NCRU I 0 A_JumpIfNoAmmo("NoAmmo")
NCRU I 0 ACS_ExecuteAlways(998,0,55,1)
Goto Fire1
Fire1:
NCRU I 0 A_PlaySoundEx("weapon/noisecrush1","Weapon")
NCRU I 0 A_FireCustomMissile("NoiseCrush",0,1,8,0)
NCRU JK 5
NCRU I 10
NCRU I 0 A_Refire
Goto Ready+1
Fire2:
NCRU I 0 
NCRU I 0 A_PlaySoundEx("weapon/noisecrush2","Weapon")
NCRU I 0 A_FireCustomMissile("NoiseCrush2",0,0,8,0)
NCRU I 0 ACS_ExecuteAlways(991,0,55)
NCRU JK 5
NCRU I 25 A_TakeInventory("NoiseCrushFlag",1)
NCRU I 0 A_Refire
Goto Ready+1
FireOut:
NCRU I 0 
NCRU I 0 A_PlaySoundEx("weapon/noisecrush2","Weapon")
NCRU I 0 A_FireCustomMissile("NoiseCrush2",0,0,8,0)
NCRU I 0 ACS_ExecuteAlways(991,0,55)
NCRU JK 5
NCRU I 25 A_TakeInventory("NoiseCrushFlag",1)
NCRU I 0 A_Refire
NCRU I 0 
Goto Deselect+1
NoAmmo:
NCRU I 1 ACS_Execute(979,0)
Goto Ready+1
}
}

actor NoiseCrushFlag : Inventory
{
inventory.amount 1
inventory.maxamount 1
}

actor NoiseCrushAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
}


actor NoiseCrush
{
PROJECTILE
Radius 5
Height 5
scale 2.5
damage (20)
damagetype "NoiseCrush1"
speed 25
+FORCEXYBILLBOARD
+HEXENBOUNCE
+DOOMBOUNCE
+CANBOUNCEWATER
BounceFactor 1.0
bouncecount 2
reactiontime 150
States
{
Spawn:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail1",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail2",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail3",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail4",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
Goto Look
Look:
TNT1 A 0 A_JumpIfCloser(40, "Give")
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail1",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
TNT1 A 0 A_JumpIfCloser(40, "Give")
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail2",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
TNT1 A 0 A_JumpIfCloser(40, "Give")
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail3",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
TNT1 A 0 A_JumpIfCloser(40, "Give")
TNT1 A 0 A_SpawnItemEx("NoiseCrushTrail4",0,0,0,0,0,0,0)
TNT1 A 1 A_CountDown
loop
Give:
TNT1 A 2 A_GiveToTarget("NoiseCrushFlag",1)
stop
}
}

actor NoiseCrush2
{
PROJECTILE
Radius 20
Height 10
scale 2.5
damage (75)
damagetype "NoiseCrush2"
+FORCEXYBILLBOARD
speed 40
reactiontime 150
States
{
Spawn:
TNT1 A 0
TNT1 A 1 A_SpawnItemEx("NoiseCrushTrail5",0,0,0,0,0,0,0)
TNT1 A 1 A_SpawnItemEx("NoiseCrushTrail6",0,0,0,0,0,0,0)
TNT1 A 1 A_SpawnItemEx("NoiseCrushTrail7",0,0,0,0,0,0,0)
TNT1 A 1 A_SpawnItemEx("NoiseCrushTrail8",0,0,0,0,0,0,0)
loop
}
}

actor NoiseCrushTrail1
{
+NOINTERACTION
+NOGRAVITY
+CLIENTSIDEONLY
+FORCEXYBILLBOARD
-SOLID
scale 2.5
height 0
radius 0
States
{
Spawn:
NCRU D 5
stop
}
}

actor NoiseCrushTrail2 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU C 5
stop
}
}

actor NoiseCrushTrail3 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU B 5
stop
}
}

actor NoiseCrushTrail4 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU A 5
stop
}
}

actor NoiseCrushTrail5 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU H 8
stop
}
}

actor NoiseCrushTrail6 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU G 8
stop
}
}

actor NoiseCrushTrail7 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU F 8
stop
}
}

actor NoiseCrushTrail8 : NoiseCrushTrail1
{
States
{
Spawn:
NCRU E 8
stop
}
}

Ad blocker interference detected!


Wikia is a free-to-use site that makes money from advertising. We have a modified experience for viewers using ad blockers

Wikia is not accessible if you’ve made further modifications. Remove the custom ad blocker rule(s) and the page will load as expected.