FANDOM


WepIconHomingSniper Homing Sniper Searchmansprite
HomingSniperWepGif
Weapon code HomingSniperWep
Comes from Mega Man 8
Weapon color scheme Dark gold on cyan
Fire rate Medium
Missile speed Slow
Capacity 14 uses (Only non charged fires)

2 uses (Only fully charged fires)

Weapon hotkey/type [2] Long range
Damage 18 [+] (One Homing Sniper missile)
Appears in
these maps
MM1BombMM4DrillMM8DuoMM5GyroMM6KnightMM6MrXMM8SearchMM8Wily1MM3ShadowMM5StoneMM8Tengu

The Homing Sniper fires slow missiles with a slight homing ability, useful in a map such as Search Man's map to hit hidden opponents. When a missile finds a target, it will quickly zoom in on a crosshair it generates on your foe. Not only can you inflict decent damage and stalk a foe at distance with single projectiles, but you can also, like in Mega Man 8, charge your weapon to cast a swarm of five in a random pattern. Missiles fired from a charged shot do not inflict more damage, but all five are likely to hit and take out more than half of someone's health. If you release a partly-charged shot, you'll consume less ammunition but fire less projectiles.

Tactics

Using Homing Sniper

Homing Sniper can be a very powerful weapon, but the seeking property of its missiles is even more finicky than Magnet Missile. The missiles will only home in on targets very close to their trajectory, and even if they do they are very easy to dodge. You'll have to time your charged barrage to hit when your opponent is moving in a straight line or changing direction. This weapon can do up to 90 damage fully charged though, so if it does hit you can finish your opponent off with the weak uncharged missiles. Finally, because the missiles need time to lock on to a target but spread out and become useless at long distances, it's best to use this weapon at mid range.

Vs. Homing Sniper

Like with Noise Crush, listen for the distinct sound a player charging Homing Sniper makes to avoid being surprised. Keep moving and try not to stop or get cornered, as a full swarm of missiles will devastate you. Try to keep back where not as many of the missiles will lock on. Luckily, the weapon only has enough ammunition for two fully charged strikes. Once those are gone, you'll have nothing to worry about from your foe.

Code

actor HomingSniperWep : MegaBuster 11097
{
//$Category MM8BDM-Weapons
Weapon.AmmoUse 2
Weapon.AmmoGive 28
Weapon.SlotNumber 2
Obituary "%o was searched and destroyed by %k's Homing Sniper."
Inventory.Pickupmessage "Power up! Homing Sniper!"
weapon.ammotype "HomingSniperAmmo"
inventory.pickupsound "weapon/weaponup"
inventory.icon "HSNIPERI"
+WEAPON.AMMO_OPTIONAL
Scale 2.0
States
{
Spawn:
WEA4 H 1
loop
Ready:
HSNI C 0 ACS_ExecuteAlways(998,0,88)
HSNI C 1 A_WeaponReady
Goto Ready+1
Deselect:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Lower
HSNI C 1
Loop
Select:
TNT1 AAAAAAAAAAAAAAAAAAAAAA 0 A_Raise
HSNI C 1
Loop
Fire:
HSNI C 0 A_JumpIfNoAmmo("NoAmmo")
HSNI C 1 //A_Refire
Goto Fire1
Hold:
HSNI C 0 A_JumpIfNoAmmo("NoAmmo")
HSNI C 0 A_JumpIfInventory("WeaponCharge",18,"Hold1")
HSNI C 1 A_GiveInventory("WeaponCharge",2)
HSNI C 0 ACS_ExecuteAlways(994,0)
HSNI C 0 A_Refire
Goto Fire1
Hold1:
HSNI C 0 A_JumpIfInventory("WeaponCharge",19,"Charge1")
HSNI C 0 A_PlaySoundEx ("weapon/chargeup","Weapon")
HSNI C 2 A_GiveInventory("WeaponCharge",1)
Charge1:
HSNI C 0 A_JumpIfInventory("WeaponCharge",34,"Charge2")
HSNI F 1 ACS_ExecuteAlways(991,0,89)
HSNI C 0 ACS_ExecuteAlways(991,0,88)
HSNI C 1 A_GiveInventory("WeaponCharge",1)
HSNI C 0 A_Refire
Goto Fire2
Charge2:
HSNI I 1 ACS_ExecuteAlways(991,0,90)
HSNI J 1 ACS_ExecuteAlways(991,0,91)
HSNI C 1 ACS_ExecuteAlways(991,0,88)
HSNI C 0 ACS_ExecuteAlways(974,0)
HSNI C 0 A_JumpIfInventory("WeaponCharge", 35, 3)
HSNI C 0 A_GiveInventory("WeaponCharge",1)
HSNI C 0 A_GunFlash
HSNI C 0 A_Refire
Goto Fire3
Fire1:
HSNI C 0 A_TakeInventory("WeaponCharge",500)
HSNI C 0 A_PlaySoundEx("weapon/coilexplode","Weapon")
HSNI C 0 A_FireCustomMissile("HomingSniper",0,1,8,0)
HSNI DE 3
HSNI C 10 
HSNI C 0 A_Refire
Goto Ready+1
Fire2:
HSNI C 0 A_TakeInventory("WeaponCharge",500)
HSNI C 0 A_PlaySoundEx("weapon/coilexplode","Weapon")
HSNI C 0 A_JumpIfInventory("HomingSniperAmmo", 4, "Fire2r")
Goto Fire1
Fire2r:
HSNI C 0 A_TakeInventory("HomingSniperAmmo",4)
HSNI C 0 A_FireCustomMissile("HomingSniper",0,0,8,0)
HSNI C 2
HSNI C 0 A_FireCustomMissile("HomingSniper",random(-5,5),0,8,0,0,random(-4,4))
HSNI DE 2
HSNI C 20
HSNI C 0 A_Refire
Goto Ready+1
Fire3:
HSNI C 0 A_TakeInventory("WeaponCharge",500)
HSNI C 0 A_PlaySoundEx("weapon/coilexplode","Weapon")
HSNI C 0 A_JumpIfInventory("HomingSniperAmmo", 10, "Fire3r")
HSNI C 0 A_JumpIfInventory("HomingSniperAmmo", 4, "Fire2r")
Goto Fire1
Fire3r:
HSNI C 0 A_TakeInventory("HomingSniperAmmo",10)
HSNI C 0 A_FireCustomMissile("HomingSniper",0,0,8,0)
HSNI C 2
HSNI C 0 A_FireCustomMissile("HomingSniper",random(-7,7),0,8,0,0,random(-4,4))
HSNI D 2
HSNI D 0 A_FireCustomMissile("HomingSniper",random(-7,7),0,8,0,0,random(-4,4))
HSNI D 2
HSNI D 0 A_FireCustomMissile("HomingSniper",random(-7,7),0,8,0,0,random(-4,4))
HSNI D 2
HSNI C 0 A_FireCustomMissile("HomingSniper",random(-7,7),0,8,0,0,random(-4,4))

/*HSNI C 2
HSNI C 0 A_FireCustomMissile("HomingSniper",-22.5,0,8,0)
HSNI C 0 A_FireCustomMissile("HomingSniper",22.5,0,8,0)
HSNI C 2
HSNI C 0 A_FireCustomMissile("HomingSniper",-45,0,8,0)
HSNI C 0 A_FireCustomMissile("HomingSniper",45,0,8,0)*/
HSNI DE 5
HSNI C 20
HSNI C 0 A_Refire
Goto Ready+1
NoAmmo:
HSNI C 1 ACS_Execute(979,0)
HSNI C 0 A_Refire
Goto Ready+1
Flash:
TNT1 H 5 A_PlaySoundEx("weapon/coilcharge", "Weapon")
TNT1 H 0 A_JumpIfInventory("WeaponCharge",1,"Flash")
stop
}
}

actor HomingSniperAmmo : Ammo
{
inventory.amount 1
inventory.maxamount 28
}


actor HomingSniper : MageStaffFX2
{
+MISSILE
+SEEKERMISSILE
-EXTREMEDEATH
Damagetype "HomingSniper"
Radius 5
Height 5
scale 2.5
damage (18)
speed 20
States
{
Spawn:
HSNM BBCCBBCC 1 A_MStaffTrack
Goto Primed
Primed:
HSNM B 1 A_MStaffTrack
HSNM B 0 A_JumpIfTargetInLOS("See", 0, 1)
HSNM B 1 A_MStaffTrack
HSNM B 0 A_JumpIfTargetInLOS("See", 0, 1)
HSNM C 1 A_MStaffTrack
HSNM B 0 A_JumpIfTargetInLOS("See", 0, 1)
HSNM C 1 A_MStaffTrack
HSNM B 0 A_JumpIfTargetInLOS("See", 0, 1)
loop
See:
HSNM BBBBBB 0 A_MStaffTrack
HSNM B 1
HSNM B 0 A_ScaleVelocity(2.0)//A_SpawnItemEx("HomingSniper2",0,0,0,momx*2,momy*2,momz*2,0,SXF_ABSOLUTEMOMENTUM|SXF_ABSOLUTEPOSITION)
Goto FastMode
FastMode:
HSNM BC 2 
HSNM B 0 A_SpawnItemEx("HomingSniperLockon",0,0,0,momx*10,momy*10,momz*10,0,SXF_ABSOLUTEMOMENTUM|SXF_ABSOLUTEPOSITION)
HSNM BC 2 
HSNM B 0 A_SpawnItemEx("HomingSniperLockon",0,0,0,momx*10,momy*10,momz*10,0,SXF_ABSOLUTEMOMENTUM|SXF_ABSOLUTEPOSITION)
HSNM BC 2 
HSNM B 0 A_SpawnItemEx("HomingSniperLockon",0,0,0,momx*10,momy*10,momz*10,0,SXF_ABSOLUTEMOMENTUM|SXF_ABSOLUTEPOSITION)
HSNM BC 2 //A_MStaffTrack
HSNM B 0 A_SpawnItemEx("HomingSniperLockon",0,0,0,momx*10,momy*10,momz*10,0,SXF_ABSOLUTEMOMENTUM|SXF_ABSOLUTEPOSITION)
Goto See+4
//loop
Death:
MMFX B 0
MMFX B 0 A_GiveToTarget("Clip", 1)
MMFX BCDE 2
stop
}
}

actor HomingSniperLockon
{
PROJECTILE
Radius 16
Height 16
scale 2.5
damage (0)
speed 80
States
{
Spawn:
TNT1 A 1
loop
XDeath:
TNT1 A 0
TNT1 A 0 A_SpawnItemEx("HomingCrosshair",8,0,8,momx,momy,momz,0,SXF_ABSOLUTEMOMENTUM)
Death:
TNT1 A 1
stop
}
}


actor HomingLockGiver : CustomInventory
{
inventory.amount 1
inventory.maxamount 1
+INVENTORY.AUTOACTIVATE
states
{
Pickup:
Use:
TNT1 A 0 A_SpawnItemEx("HomingCrosshair",8,0,20,momx,momy,momz,0,SXF_ABSOLUTEMOMENTUM)
stop
}
}


actor HomingCrosshair
{
+CLIENTSIDEONLY
+NOINTERACTION
-SOLID
+NOGRAVITY
Scale 2.5
States
{
Spawn:
HSNI KKK 2
stop
}
}

Ad blocker interference detected!


Wikia is a free-to-use site that makes money from advertising. We have a modified experience for viewers using ad blockers

Wikia is not accessible if you’ve made further modifications. Remove the custom ad blocker rule(s) and the page will load as expected.